Sub LoadTagsAsSymbols()

Dim XL As Excel.Application
Set XL = New Excel.Application

Dim WB As Excel.Workbook
Set WB = XL.Workbooks.Open("C:\LoadTags.xlsx")

Dim WS As Worksheet
Set WS = WB.Worksheets("TAGS")

Dim Val As Text
Dim i As Integer, iLeft As Integer, iTop As Integer

iLeft = -15000: iTop = 15000

For i = 1 To 1000
    If WS.Range("A" & i).Value = "" Then Exit For
   
    Set Val = ThisDisplay.Symbols.Add(pbSymbolText)
        Val.Left = iLeft
        Val.Top = iTop
        Val.Contents = WS.Range("B" & i).Value
       
        If (iTop - Val.Height - 5) < (ThisDisplay.ViewTop - ThisDisplay.ViewHeight) Then
            iTop = 15000
            iLeft = iLeft + Val.Width + 1
        Else
            iTop = iTop - Val.Height - 5
        End If

        Dim MSS As MultiState
        Set MSS = Val.CreateMultiState(WS.Range("A" & i).Value)
            MSS.BlinkBadData = True
            MSS.ColorBadData = pbRed
           
        Dim MS As MSState, iMS As Integer
        For iMS = 1 To MSS.StateCount
            Set MS = MSS.GetState(iMS)
                MS.Blink = False
                MS.Color = pbBlack
            Set MS = Nothing
        Next iMS
       
        Set MSS = Nothing
    Set Val = Nothing
Next i

Set WS = Nothing

Call WB.Close(False)
Set WB = Nothing

XL.Quit
Set XL = Nothing

End Sub